cmake_minimum_required(VERSION 3.10)
project(armor_yolo_detect)

## Set CMake policy to suppress OpenGL warning
cmake_policy(SET CMP0072 NEW)

## Use C++17
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

## Export compile commands for clangd
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

#######################
## Find dependencies ##
#######################

find_package(ament_cmake_auto REQUIRED)
find_package(OpenCV REQUIRED)
find_package(fmt REQUIRED)
find_package(Sophus REQUIRED)
find_package(armor_detector REQUIRED)
ament_auto_find_build_dependencies()

# TensorRT
find_package(CUDA REQUIRED)

###########
## Build ##
###########

ament_auto_add_library(${PROJECT_NAME} SHARED
  src/armor_yolo_detector.cpp
  src/armor_yolo_detector_node.cpp
  src/async_detector.cpp
  src/trt_logger.cpp
  src/yolo_tensorrt.cpp
)

ament_auto_add_executable(trt_inference_test
  trt_inference/trt_inference_test.cpp
)

set(ONNXRUNTIME_ROOT ${CMAKE_CURRENT_SOURCE_DIR}/third_party/onnxruntime)
set(ONNXRUNTIME_INCLUDE_DIR ${ONNXRUNTIME_ROOT}/include)
set(ONNXRUNTIME_LIB_DIR ${ONNXRUNTIME_ROOT}/lib)

target_include_directories(trt_inference_test PRIVATE
  ${ONNXRUNTIME_INCLUDE_DIR}
)

target_link_directories(trt_inference_test PRIVATE
  ${ONNXRUNTIME_LIB_DIR}
)

target_link_libraries(trt_inference_test
  ${PROJECT_NAME}
  ${OpenCV_LIBS}
  onnxruntime
)

set_target_properties(trt_inference_test PROPERTIES
  BUILD_RPATH "${ONNXRUNTIME_LIB_DIR}"
  INSTALL_RPATH "\$ORIGIN/../../share/${PROJECT_NAME}/third_party/onnxruntime/lib"
)

target_include_directories(${PROJECT_NAME} PUBLIC
  ${OpenCV_INCLUDE_DIRS}
  ${EIGEN3_INCLUDE_DIRS}
  ${Sophus_INCLUDE_DIRS}
  ${CUDA_INCLUDE_DIRS}
)

target_link_libraries(${PROJECT_NAME}
  ${OpenCV_LIBS}
  ${CUDA_LIBRARIES}
  nvinfer
  nvinfer_plugin
  nvonnxparser
  fmt::fmt
  armor_detector
)

rclcpp_components_register_node(${PROJECT_NAME}
  PLUGIN armor_yolo_detect::ArmorYoloDetectorNode
  EXECUTABLE armor_yolo_detector_node
)

#############
## Testing ##
#############

if(BUILD_TESTING)
  find_package(ament_lint_auto REQUIRED)
  list(APPEND AMENT_LINT_AUTO_EXCLUDE
    ament_cmake_copyright
    ament_cmake_uncrustify
    ament_cmake_cpplint
    ament_cmake_lint_cmake
  )
  ament_lint_auto_find_test_dependencies()
endif()

#############
## Install ##
#############

ament_auto_package(
  USE_SCOPED_HEADER_INSTALL_DIR
  INSTALL_TO_SHARE
  config
  model
  launch
  third_party
)
